open import Cat.Instances.Elements.Covariant
open import Cat.Diagram.Coproduct.Copower
open import Cat.Diagram.Coproduct.Indexed
open import Cat.Functor.Hom.Representable
open import Cat.Functor.Equivalence.Path
open import Cat.Instances.Sets.Complete
open import Cat.Functor.Adjoint.Hom
open import Cat.Functor.Equivalence
open import Cat.Functor.Hom.Duality
open import Cat.Instances.Functor
open import Cat.Diagram.Terminal
open import Cat.Diagram.Initial
open import Cat.Functor.Adjoint
open import Cat.Instances.Comma
open import Cat.Instances.Sets
open import Cat.Functor.Hom
open import Cat.Prelude

import Cat.Reasoning

open Corepresentation
open Representation
open Functor

module Cat.Functor.Adjoint.Representable {o ℓ} {C : Precategory o ℓ} where

Adjoints in terms of representability🔗

Building upon our characterisation of adjoints as Hom isomorphisms, we now investigate the relationship between adjoint functors and representable functors.

In this section, we show that for a functor $R:\mathcal{C}\to \mathcal{D}$ to be a right adjoint is equivalent to the functor ${\mathbf{Hom}}_{\mathcal{D}}(d,R-):\mathcal{C}\to \mathbf{Sets}$ having a representing object for all $d:\mathcal{D}\text{.}$

The forward direction follows directly from the natural isomorphism ${\mathbf{Hom}}_{\mathcal{C}}(Ld,-)\cong {\mathbf{Hom}}_{\mathcal{D}}(d,R-)\text{,}$ which exhibits $Ld$ as a representing object.

module _ {o'} {D : Precategory o' ℓ}
  {L : Functor D C} {R : Functor C D} (L⊣R : L ⊣ R)
  where

  right-adjoint→objectwise-rep
    : ∀ d → Corepresentation (Hom-from D d F∘ R)
  right-adjoint→objectwise-rep d .corep = L .F₀ d
  right-adjoint→objectwise-rep d .corepresents =
    adjunct-hom-iso-from L⊣R d ni⁻¹

  left-adjoint→objectwise-rep
    : ∀ c → Corepresentation (Hom-into C c F∘ Functor.op L)
  left-adjoint→objectwise-rep c .corep = R .F₀ c
  left-adjoint→objectwise-rep c .corepresents =
    path→iso (sym (Hom-from-op _))
    ∘ni adjunct-hom-iso-into L⊣R c

The other direction should be more surprising: if we only have a family of objects $Ld$ representing the functors ${\mathbf{Hom}}_{\mathcal{D}}(d,R-)\text{,}$ why should we expect them to assemble into a functor $L:\mathcal{D}\to \mathcal{C}\text{?}$

We answer the question indirectly¹: what is a sufficient condition for $R$ to have a left adjoint? Well, by our characterisation in terms of free objects, it should be enough to have initial objects for each comma category $d\swarrow R\text{.}$ But we have also established that a (covariant) functor into $\mathbf{Sets}$ is representable if and only if its category of elements has an initial object.

Now we simply observe that the comma category $d\swarrow R$ and the category of elements of ${\mathbf{Hom}}_{\mathcal{D}}(d,R-)$ are exactly the same: both are made out of pairs of an object $c:\mathcal{C}$ and a map $d\to Rc\text{,}$ with the morphisms between them obtained in the obvious way from morphisms in $\mathcal{C}\text{.}$

module _ {o'} {D : Precategory o' ℓ}
  {R : Functor C D}
  (corep : ∀ d → Corepresentation (Hom-from D d F∘ R))
  where

  private
    module D = Cat.Reasoning D

  private
    ↙≡∫ : ∀ d → d ↙ R ≡ ∫ (Hom-from D d F∘ R)

    ↙≡∫ d = Precategory-path F F-is-precat-iso where
      open is-precat-iso

      F : Functor (d ↙ R) (∫ (Hom-from D d F∘ R))
      F .F₀ m = elem (m .↓Obj.y) (m .↓Obj.map)
      F .F₁ f = elem-hom (f .↓Hom.β) (sym (f .↓Hom.sq) ∙ D.idr _)
      F .F-id = ext refl
      F .F-∘ f g = ext refl

      F-is-precat-iso : is-precat-iso F
      F-is-precat-iso .has-is-iso = is-iso→is-equiv record where
        from e = ↓obj (e .Element.section)
        rinv e = refl
        linv e = ↓Obj-path _ _ refl refl refl
      F-is-precat-iso .has-is-ff = is-iso→is-equiv record where
        from h = ↓hom (D.idr _ ∙ sym (h .Element-hom.commute))
        rinv h = ext refl
        linv h = ↓Hom-path _ _ refl refl

  objectwise-rep→universal-maps : ∀ d → Universal-morphism R d
  objectwise-rep→universal-maps d = subst Initial (sym (↙≡∫ d))
    (corepresentation→initial-element (corep d))

  objectwise-rep→functor : Functor D C
  objectwise-rep→functor =
    universal-maps→functor objectwise-rep→universal-maps

  objectwise-rep→left-adjoint : objectwise-rep→functor ⊣ R
  objectwise-rep→left-adjoint =
    universal-maps→left-adjoint objectwise-rep→universal-maps

Right adjoints into Sets are representable🔗

For functors into ${\mathbf{Sets}}_{\ell }\text{,}$ we can go one step further: under certain conditions, being a right adjoint is equivalent to being representable.

Indeed, if $R$ has a left adjoint $L:{\mathbf{Sets}}_{\ell }\to \mathcal{C}\text{,}$ then $R$ is automatically represented by $L\{\ast \}\text{,}$ the image of the singleton set by $L\text{,}$ because we have ${\mathbf{Hom}}_{\mathcal{C}}(L\{\ast \},c)\cong (\{\ast \}\to Rc)\cong Rc\text{.}$

module _
  {R : Functor C (Sets ℓ)} {L : Functor (Sets ℓ) C} (L⊣R : L ⊣ R)
  where

  open Terminal (Sets-terminal {ℓ})

  right-adjoint→corepresentable : Corepresentation R
  right-adjoint→corepresentable .corep = L .F₀ top
  right-adjoint→corepresentable .corepresents =
    adjunct-hom-iso-from L⊣R top ni⁻¹
    ∘ni iso→isoⁿ (λ _ → equiv→iso (Π-⊤-eqv e⁻¹)) (λ _ → refl)

Going the other way, if we assume that $\mathcal{C}$ is copowered over ${\mathbf{Sets}}_{\ell }$ (in other words, that it admits $\ell \text{-small}$ indexed coproducts), then any functor $R$ with representing object $c$ has a left adjoint given by taking copowers of $c\text{:}$ for any set $X\text{,}$ we have ${\mathbf{Hom}}_{\mathcal{C}}(X\otimes c,-)\cong (X\to {\mathbf{Hom}}_{\mathcal{C}}(c,-))\cong (X\to R-)\text{.}$

module _
  (copowered : has-indexed-coproducts C ℓ)
  {R : Functor C (Sets ℓ)} (R-corep : Corepresentation R)
  where

  private
    open Copowers (λ _ → copowered)

    Hom[X,R-]-rep : ∀ X → Corepresentation (Hom-from (Sets ℓ) X F∘ R)
    Hom[X,R-]-rep X .corep = X ⊗ R-corep .corep
    Hom[X,R-]-rep X .corepresents =
      copower-hom-iso ni⁻¹
      ∘ni F∘-iso-r (R-corep .corepresents)

  corepresentable→functor : Functor (Sets ℓ) C
  corepresentable→functor = objectwise-rep→functor Hom[X,R-]-rep

  corepresentable→left-adjoint : corepresentable→functor ⊣ R
  corepresentable→left-adjoint = objectwise-rep→left-adjoint Hom[X,R-]-rep