🔍

Equations Inline Footnotes

open import Cat.Functor.Equivalence.Path
open import Cat.Functor.Equivalence
open import Cat.Prelude

import Cat.Instances.Elements as Contra

module Cat.Instances.Elements.Covariant where

module _ {o ℓ s} {C : Precategory o ℓ} (P : Functor C (Sets s)) where
  private module P = Functor P

  open Precategory C
  open Functor

The covariant category of elements🔗

While the category of elements comes up most often in the context of presheaves (i.e., contravariant functors into $\mathbf{Sets}\text{),}$ the construction makes sense for covariant functors as well.

Sadly, we cannot simply reuse the contravariant construction, instantiating $\mathcal{C}$ as ${\mathcal{C}}^{\mathrm{op}}\text{:}$ the resulting category would be the opposite of what we want. Indeed, in both the covariant and contravariant cases, we want the projection $\pi :\int F\to \mathcal{C}$ to be covariant.

Thus we proceed to dualise the whole construction.

  Element : Type (o ⊔ s)
  Element = Σ[ ob ∈ Ob ] P ʻ ob

  pattern elem x s = x , s

  record Element-hom (x y : Element) : Type (ℓ ⊔ s) where
    constructor elem-hom
    field
      hom     : Hom (x .fst) (y .fst)
      commute : P.₁ hom (x .snd) ≡ y .snd

  open Element-hom

  Element-hom-path : {x y : Element} {f g : Element-hom x y} → f .hom ≡ g .hom → f ≡ g
  Element-hom-path p i .hom = p i
  Element-hom-path {x = x} {y = y} {f = f} {g = g} p i .commute =
    is-prop→pathp (λ j → P.₀ (y .fst) .is-tr (P.₁ (p j) (x .snd)) (y .snd))
      (f .commute)
      (g .commute) i

unquoteDecl H-Level-Element-hom = declare-record-hlevel  H-Level-Element-hom (quote Element-hom)

module _ {o ℓ s} {C : Precategory o ℓ} {P : Functor C (Sets s)} where instance
  Extensional-element-hom
    : ∀ {x y : Element P} {ℓr}
    → ⦃ ext : Extensional (C .Precategory.Hom (x .fst) (y .fst)) ℓr ⦄
    → Extensional (Element-hom P x y) ℓr
  Extensional-element-hom ⦃ ext ⦄ = injection→extensional
    (C .Precategory.Hom-set _ _) (Element-hom-path P) ext

module _ {o ℓ s} {C : Precategory o ℓ} (P : Functor C (Sets s)) where
  private module P = Functor P

  open Precategory C
  open Element-hom
  open Functor

  ∫ : Precategory (o ⊔ s) (ℓ ⊔ s)
  ∫ .Precategory.Ob = Element P
  ∫ .Precategory.Hom = Element-hom P
  ∫ .Precategory.Hom-set _ _ = hlevel 
  ∫ .Precategory.id {x = x} = elem-hom id λ i → P.F-id i (x .snd)
  ∫ .Precategory._∘_ {x = x} {y = y} {z = z} f g = elem-hom (f .hom ∘ g .hom) comm where abstract
    comm : P.₁ (f .hom ∘ g .hom) (x .snd) ≡ z .snd
    comm =
      P.₁ (f .hom ∘ g .hom) (x .snd)       ≡⟨ happly (P.F-∘ (f .hom) (g .hom)) (x .snd) ⟩≡
      P.₁ (f .hom) (P.₁ (g .hom) (x .snd)) ≡⟨ ap (P.F₁ (f .hom)) (g .commute)  ⟩≡
      P.₁ (f .hom) (y .snd)                ≡⟨ f .commute ⟩≡
      z .snd ∎
  ∫ .Precategory.idr f = ext (idr (f .hom))
  ∫ .Precategory.idl f = ext (idl (f .hom))
  ∫ .Precategory.assoc f g h = ext (assoc (f .hom) (g .hom) (h .hom))

  πₚ : Functor ∫ C
  πₚ .F₀ x = x .fst
  πₚ .F₁ f = f .hom
  πₚ .F-id = refl
  πₚ .F-∘ f g = refl

We can now relate the two constructions: the covariant category of elements of $P$ is the opposite of the contravariant category of elements of $P$ seen as a contravariant functor on ${\mathcal{C}}^{\mathrm{op}}$ (thus a functor $({\mathcal{C}}^{\mathrm{op}}{)}^{\mathrm{op}}=\mathcal{C}\to \mathbf{Sets}\text{).}$

  co-∫ : ∫ ≡ Contra.∫ (C ^op) (record { Functor P }) ^op
  co-∫ = Precategory-path F F-is-precat-iso where
    F : Functor ∫ (Contra.∫ (C ^op) (record { Functor P }) ^op)
    F .F₀ e = e
    F .F₁ h = Contra.elem-hom (h .hom) (h .commute)
    F .F-id = refl
    F .F-∘ _ _ = ext refl

    F-is-precat-iso : is-precat-iso F
    F-is-precat-iso .is-precat-iso.has-is-iso = id-equiv
    F-is-precat-iso .is-precat-iso.has-is-ff = is-iso→is-equiv λ where
      .is-iso.from h → elem-hom (h .Contra.Element-hom.hom) (h .Contra.Element-hom.commute)
      .is-iso.rinv h → ext refl
      .is-iso.linv h → ext refl