{-# OPTIONS --lossy-unification #-}
open import Cat.Functor.Equivalence
open import Cat.Functor.Properties
open import Cat.Instances.Functor
open import Cat.Functor.Compose
open import Cat.Univalent
open import Cat.Prelude

import Cat.Functor.Reasoning.FullyFaithful as FfR
import Cat.Functor.Reasoning as FR
import Cat.Reasoning

open Functor
open _=>_

module Cat.Univalent.Rezk.Universal where

private variable
  o ℓ : Level
  A B C C⁺ : Precategory o ℓ

private module _ {o ℓ} {C : Precategory o ℓ} where
  open Cat.Reasoning C using (_≅_)
  open _≅_ public

-- Using ∙/·· over equational reasoning saves ~5k conversion checks

Universal property of the Rezk completion🔗

With the Rezk completion, we defined, for any precategory $\mathcal{C}\text{,}$ a univalent category ${\mathcal{C}}^{+}\text{,}$ together with a weak equivalence functor $R:\mathcal{C}\to {\mathcal{C}}^{+}\text{.}$ We also stated, but did not in that module prove, the universal property of the Rezk completion: The functor $R$ is the universal map from $\mathcal{C}$ to categories. This module actually proves it, but be warned: the proof is very technical, and is mostly a calculation.

In generic terms, universality of the Rezk completion follows from univalent categories being the class of local objects for the weak equivalences¹: A category $\mathcal{C}$ is univalent precisely if any weak equivalence $H:\mathcal{A}\to \mathcal{B}$ induces² a proper equivalence of categories $-\circ H:[\mathcal{B},\mathcal{C}]\to [\mathcal{A},\mathcal{C}]\text{.}$

The high-level overview of the proof is as follows:

• For any eso functor $H:\mathcal{A}\to \mathcal{B}\text{,}$ and for any $\mathcal{C}\text{,}$ all precategories, the functor $-\circ H:[\mathcal{A},\mathcal{B}]\to [\mathcal{B},\mathcal{C}]$ is faithful. This is the least technical part of the proof, so we do it first.

• If $H$ is additionally full, then $-\circ H$ is fully faithful.

• If $H$ is a weak equivalence, and $\mathcal{C}$ is univalent, then $-\circ H$ is essentially surjective. By the principle of unique choice, it is an equivalence, and thus³ an isomorphism.

Faithfulness🔗

The argument here is almost elementary: We’re given a witness that $\gamma H=\delta H\text{,}$ so all we have to do is manipulate the expression ${\gamma }_b$ to something which has a $\gamma H$ subexpression. Since $H$ is eso, given $b:\mathcal{B}\text{,}$ we can find $a:\mathcal{A}$ and an iso $m:Ha\cong b\text{,}$ from which we can calculate:

eso→pre-faithful
  : (H : Functor A B) {F G : Functor B C}
  → is-eso H → (γ δ : F => G)
  → (∀ b → γ .η (H .F₀ b) ≡ δ .η (H .F₀ b)) → γ ≡ δ
eso→pre-faithful {A = A} {B = B} {C = C} H {F} {G} h-eso γ δ p = ext λ b →
  ∥-∥-out (C.Hom-set _ _ _ _) do
  (b' , m) ← h-eso b
  ∥_∥.inc $
    γ .η b                                      ≡⟨ C.intror (F-map-iso F m .invl) ⟩≡
    γ .η b C.∘ F.₁ (m .to) C.∘ F.₁ (m .from)    ≡⟨ C.extendl (γ .is-natural _ _ _) ⟩≡
    G.₁ (m .to) C.∘ γ .η _ C.∘ F.₁ (m .from)    ≡⟨ ap₂ C._∘_ refl (ap₂ C._∘_ (p b') refl) ⟩≡
    G.₁ (m .to) C.∘ δ .η _ C.∘ F.₁ (m .from)    ≡⟨ C.extendl (sym (δ .is-natural _ _ _)) ⟩≡
    δ .η b C.∘ F.₁ (m .to) C.∘ F.₁ (m .from)    ≡⟨ C.elimr (F-map-iso F m .invl) ⟩≡
    δ .η b                                      ∎
  where module C = Cat.Reasoning C
        module F = Functor F
        module G = Functor G

The above is, unfortunately, the simplest result in this module. The next two proofs are both quite technical: that’s because we’re given some mere⁴ data, from the assumption that $H$ is a weak equivalence, so to use it as proper data, we need to show that whatever we want lives in a contractible space, after which we are free to project only the data we are interested in, and forget about the coherences.

It will turn out, however, that the coherence data necessary to make these types contractible is exactly the coherence data we need to show that we are indeed building functors, natural transformations, etc. So, not only do we need it to use unique choice, we also need it to show we’re doing category theory.

Full-faithfulness🔗

Let $A\text{,}$ $B\text{,}$ $C$ and $H$ be as before, except now assume that $H$ is full (in addition to eso).

eso-full→pre-ff
  : (H : Functor A B)
  → is-eso H → is-full H
  → is-fully-faithful {C = Cat[ B , C ]} (precompose H)
eso-full→pre-ff {A = A} {B = B} {C = C} H H-eso H-full = res where

We will show that, for every natural transformation $\gamma :FH\to GH\text{,}$ and each $b:\mathcal{B}\text{,}$ there is a contractible type of “component data” over $b\text{.}$ These data consist of morphisms $g:Fb\to Gb\text{,}$ each equipped with a witness that $g$ acts naturally when faced with isomorphisms $Ha\cong b\text{.}$

  module A = Cat.Reasoning A
  module B = Cat.Reasoning B
  module C = Cat.Reasoning C
  module H = FR H

  module _ (F G : Functor B C) (γ : F F∘ H => G F∘ H) where
    module F = FR F
    module FH = FR (F F∘ H)
    module G = FR G
    module GH = FR (G F∘ H)
    module γ = _=>_ γ

In more detail, if we’re given an essential fibre $(a,f)$ of $H$ over $b\text{,}$ we can use $f$ to “match up” our component $g$ with the components of the natural transformation $\gamma \text{:}$ since ${\gamma }_a:FH(a)\to FG(a)\text{,}$ we’ve claimed to have a $Fb\to Gb\text{,}$ and someone has just handed us a $H(a)\cong b\text{,}$ then it darn well better be the case that $\gamma$ is

    T : B.Ob → Type _
    T b = Σ (C.Hom (F.₀ b) (G.₀ b)) λ g →
      (a : A.Ob) (f : H.₀ a B.≅ b) →
      γ.η a ≡ G.₁ (f .from) C.∘ g C.∘ F.₁ (f .to)

We’ll first show that components exist at all. Assume that we have some $b:\mathcal{B}$ and an essential fibre $(a_0,h_0)$ of $H$ over it⁵. In this situation, guided by the compatibility condition (and isomorphisms being just the best), we can actually define the component to be “whatever satisfies compatibility at $(a_0,h_0)\text{,}$” and a short calculation establishes that defining

    module Mk (b : B.Ob) (a₀ : A.Ob) (h : H.₀ a₀ B.≅ b) where
      private module h = B._≅_ h

      g = G.₁ h.to C.∘ γ.η a₀ C.∘ F.₁ h.from

is indeed a possible choice. We present the formalisation below, but do not comment on the calculation, leaving it to the curious reader to load this file in Agda and poke around the proof.

      lemma : (a : A.Ob) (f : H.₀ a B.≅ b)
            → γ.η a ≡ G.₁ (f .from) C.∘ g C.∘ F.₁ (f .to)
      lemma a f = ∥-∥-out (C.Hom-set _ _ _ _) do
        (k , p)   ← H-full (h.from B.∘ B.to f)
        (k⁻¹ , q) ← H-full (B.from f B.∘ h.to)
        ∥_∥.inc $
             C.intror (F.annihilate
               (ap₂ B._∘_ q p ·· B.cancel-inner h.invl ·· f .invr))
          ·· C.extendl (γ.is-natural _ _ _)
          ·· ap₂ (λ e e' → G.₁ e C.∘ γ.η a₀ C.∘ F.₁ e') q p
          ·· ap₂ (λ e e' → e C.∘ γ.η a₀ C.∘ e') (G.F-∘ _ _) (F.F-∘ _ _)
          ·· C.pullr (ap (G.₁ h.to C.∘_) (C.pulll refl) ∙ C.pulll refl)

Anyway, because of how we’ve phrased the coherence condition, if $g\text{,}$ $g^{\prime }$ both satisfy it, then we have $\gamma$ equal to both $G(h)gF(h^{-1})$ and $G(h)g^{\prime }F(h^{-1})\text{.}$⁶ Since isomorphisms are both monic and epic, we can cancel $G(h)$ and $F(h^{-1})$ from these equations to conclude $g=g^{\prime }\text{.}$ Since the coherence condition is a proposition, the type of component data over $b$ is a proposition.

    T-prop : ∀ b → is-prop (T b)
    T-prop b (g , coh) (g' , coh') = Σ-prop-path! $ ∥-∥-out! do
      (a₀ , h) ← H-eso b
      pure $ C.iso→epic (F-map-iso F h) _ _
        (C.iso→monic (F-map-iso G (h B.Iso⁻¹)) _ _
          (sym (coh a₀ h) ∙ coh' a₀ h))

Given any $b\text{,}$ $H$ being eso means that we merely have an essential fibre $(a,h)$ of $H$ over $b\text{.}$ But since the type of components over $b$ is a proposition, if we’re going to use it to construct a component over $b\text{,}$ then we are granted the honour of actually getting hold of an $(a,h)$ pair.

    mkT' : ∀ b → ∥ Essential-fibre H b ∥ → ∥ T b ∥
    mkT' b he = do
      (a₀ , h) ← he
      ∥_∥.inc (Mk.g b a₀ h , Mk.lemma b a₀ h)

    mkT : ∀ b → T b
    mkT b = ∥-∥-out (T-prop b) (mkT' b (H-eso b))

Another calculation shows that, since $H$ is full, given any pair of essential fibres $(a,h)$ over $b$ and $(a^{\prime },h^{\prime })$ over $b^{\prime }\text{,}$ with a mediating map $f:b\to b^{\prime }\text{,}$ we can choose a map $k:Ha\to H{a}^{\prime }$ satisfying $Hk=h^{\prime }fh\text{,}$ and since both the components at $b$ and $b$ “come from $\gamma$” (which is natural), we get a naturality result for the transformation we’re defining, too.

    module
      _ {b b'} (f : B.Hom b b') (a a' : A.Ob)
        (h : H.₀ a B.≅ b) (h' : H.₀ a' B.≅ b')
      where
      private
        module h' = B._≅_ h'
        module h = B._≅_ h

      naturality : _
      naturality = ∥-∥-out (C.Hom-set _ _ _ _) do
        (k , p) ← H-full (h'.from B.∘ f B.∘ h.to)
        pure $ C.pullr (C.pullr (F.weave (sym
                  (B.pushl p ∙ ap₂ B._∘_ refl (B.cancelr h.invl)))))
            ·· ap₂ C._∘_ refl (C.extendl (γ.is-natural _ _ _))
            ·· C.extendl (G.weave (B.lswizzle p h'.invl))

Because of this naturality result, all the components we’ve chosen piece together into a natural transformation. And since we defined $\delta$ parametrically over the choice of essential fibre, if we’re looking at some $Hb\text{,}$ then we can choose the identity isomorphism, from which it falls out that $\delta H=\gamma \text{.}$ Since we had already established that $-\circ H$ is faithful, and now we’ve shown it is full, it is fully faithful.

    δ : F => G
    δ .η b = mkT b .fst
    δ .is-natural b b' f = ∥-∥-elim₂
      {P = λ α β → ∥-∥-out (T-prop b') (mkT' b' α) .fst C.∘ F.₁ f
                 ≡ G.₁ f C.∘ ∥-∥-out (T-prop b) (mkT' b β) .fst}
      (λ _ _ → C.Hom-set _ _ _ _)
      (λ (a' , h') (a , h) → naturality f a a' h h') (H-eso b') (H-eso b)

  full : is-full (precompose H)
  full {x = x} {y = y} γ = pure (δ _ _ γ , ext p) where
    p : ∀ b → δ _ _ γ .η (H.₀ b) ≡ γ .η b
    p b = subst
      (λ e → ∥-∥-out (T-prop _ _ γ (H.₀ b)) (mkT' _ _ γ (H.₀ b) e) .fst
           ≡ γ .η b)
      (squash (inc (b , B.id-iso)) (H-eso (H.₀ b)))
      (C.eliml (y .F-id) ∙ C.elimr (x .F-id))

  res : is-fully-faithful (precompose H)
  res = full+faithful→ff (precompose H) full λ {F} {G} {γ} {δ} p →
    eso→pre-faithful H H-eso γ δ λ b → p ηₚ b

Essential surjectivity🔗

The rest of the proof proceeds in this same way: Define a type which characterises, up to a compatible space of choices, first the action on morphisms of a functor which inverts $-\circ H\text{,}$ and in terms of this type, the action on morphisms. It’s mostly the same trick as above, but a lot wilder. We do not comment on it too extensively: the curious reader, again, can load this file in Agda and play around.

module
  _ {ao aℓ bo bℓ co cℓ}
    {A : Precategory ao aℓ} {B : Precategory bo bℓ} {C : Precategory co cℓ}
    (H : Functor A B) (H-eso : is-eso H) (H-ff : is-fully-faithful H)
    (c-cat : is-category C)
  where

  private
    module A = Cat.Reasoning A
    module B = Cat.Reasoning B
    module C = Cat.Reasoning C
    module H = FfR H H-ff

The type of object-candidates Obs is indexed by a $b:\mathcal{B}\text{,}$ and any object candidate $c$ must come with a family of isomorphisms $k_h$ giving, for every way of expressing $b$ as coming from $Ha\text{,}$ a way of $c$ coming from $Fa\text{.}$ To show this type is a proposition, we additionally require a naturality condition for these isomorphisms.

  private module _ (F : Functor A C) where
    private module F = FR F

    Obs : B.Ob → Type _
    Obs b =
      Σ C.Ob λ c →
      Σ ((a : A.Ob) (h : H.₀ a B.≅ b) → F.₀ a C.≅ c) λ k →
      ((a , h) (a' , h') : Essential-fibre H b) (f : A.Hom a a') →
      h' .to B.∘ H.₁ f ≡ h .to →
      k a' h' .to C.∘ F.₁ f ≡ k a h .to

Note that we can derive an object candidate over $b$ from a fibre $(a,h)$ of $H$ over $b\text{.}$ Moreover, this choice is a center of contraction, so we can once more apply unique choice and the assumption that $H$ is eso to conclude that every $b:\mathcal{B}$ has an object candidate over it.

    obj' : ∀ {b} → Essential-fibre H b → Obs b
    obj' (a₀ , h₀) .fst = F.₀ a₀
    obj' (a₀ , h₀) .snd .fst a h = F-map-iso F (H.iso.from (h B.∘Iso (h₀ B.Iso⁻¹)))
    obj' (a₀ , h₀) .snd .snd (a , h) (a' , h') f p = F.collapse (H.ipushr p)

    Obs-is-prop : ∀ {b} (f : Essential-fibre H b) (c : Obs b) → obj' f ≡ c
    Obs-is-prop (a₀ , h₀) (c' , k' , β) =
      Σ-pathp (Univalent.iso→path c-cat c≅c') $
      Σ-prop-pathp! $
        funextP λ a → funextP λ h → C.≅-pathp _ _ $
          Univalent.Hom-pathp-reflr-iso c-cat {q = c≅c'}
            ( C.pullr (F.eliml (H.from-id (h₀ .invr)))
            ∙ β _ _ _ (H.ε-lswizzle (h₀ .invl)))
      where
        ckα = obj' (a₀ , h₀)
        c = ckα .fst
        k = ckα .snd .fst
        α = ckα .snd .snd
        c≅c' = (k a₀ h₀ C.Iso⁻¹) C.∘Iso k' a₀ h₀

    summon : ∀ {b} → ∥ Essential-fibre H b ∥ → is-contr (Obs b)
    summon f = ∥-∥-out is-contr-is-prop do
      f ← f
      pure $ contr (obj' f) (Obs-is-prop f)

    G₀ : B.Ob → C.Ob
    G₀ b = summon {b = b} (H-eso b) .centre .fst

    k : ∀ {b} a (h : H.₀ a B.≅ b) → F.₀ a C.≅ G₀ b
    k {b = b} a h = summon {b = b} (H-eso b) .centre .snd .fst a h

    kcomm
      : ∀ {b} ((a , h) (a' , h') : Essential-fibre H b) (f : A.Hom a a')
      → h' .to B.∘ H.₁ f ≡ h .to → k a' h' .to C.∘ F.₁ f ≡ k a h .to
    kcomm {b} f1 f2 f w = summon {b = b} (H-eso b) .centre .snd .snd f1 f2 f w

We will write G₀ for the canonical choice of object candidate, and k for the associated family of isomorphisms. The type of morphism candidates over $f:b\to b^{\prime }$ consists of maps $G_0(b)\to G_0(b^{\prime })$ which are compatible with the reindexing isomorphisms $k$ for any essential fibre $(a,h)$ over $b\text{,}$ $(a^{\prime },h^{\prime })$ over $b^{\prime }\text{,}$ and map $l:a\to a^{\prime }$ satisfying $h^{\prime }H(l)=fh\text{.}$

    compat : ∀ {b b'} (f : B.Hom b b') → C.Hom (G₀ b) (G₀ b') → Type _
    compat {b} {b'} f g =
      ∀ a (h : H.₀ a B.≅ b) a' (h' : H.₀ a' B.≅ b') (l : A.Hom a a')
      → h' .to B.∘ H.₁ l ≡ f B.∘ h .to
      → k a' h' .to C.∘ F.₁ l ≡ g C.∘ k a h .to

    Homs : ∀ {b b'} (f : B.Hom b b') → Type _
    Homs {b = b} {b'} f = Σ (C.Hom (G₀ b) (G₀ b')) (compat f)

    module _ {b b'} (f : B.Hom b b')
             a₀ (h₀ : H.₀ a₀ B.≅ b)
             a₀' (h₀' : H.₀ a₀' B.≅ b') where
      l₀ : A.Hom a₀ a₀'
      l₀ = H.from (h₀' .from B.∘ f B.∘ h₀ .to)

      p : h₀' .to B.∘ H.₁ l₀ ≡ (f B.∘ h₀ .to)
      p = H.ε-lswizzle (h₀' .invl)

      g₀ : C.Hom (G₀ b) (G₀ b')
      g₀ = k a₀' h₀' .to C.∘ F.₁ l₀ C.∘ k a₀ h₀ .from

      module _ a (h : H.₀ a B.≅ b) a' (h' : H.₀ a' B.≅ b')
                (l : A.Hom a a') (w : h' .to B.∘ H.₁ l ≡ f B.∘ h .to) where
        m : a₀ A.≅ a
        m = H.iso.from (h₀ B.∘Iso (h B.Iso⁻¹))

        m' : a₀' A.≅ a'
        m' = H.iso.from (h₀' B.∘Iso (h' B.Iso⁻¹))

        α : k a₀ h₀ .from ≡ F.₁ (m .from) C.∘ k a h .from
        α = C.inverse-unique _ _ (k a₀ h₀) (F-map-iso F m C.∘Iso k a h) $
          sym (kcomm _ _ _ (H.ε-lswizzle (h .invl)))

        γ : H.₁ (m' .to) B.∘ H.₁ l₀ ≡ H.₁ l B.∘ H.₁ (m .to)
        γ =  B.pushl (H.ε _)
          ·· ap₂ B._∘_ refl (p ∙
              B.pushl (B.insertr (h .invl) ∙ ap₂ B._∘_ (sym w) refl))
          ·· B.deletel (h' .invr)
          ∙ ap₂ B._∘_ refl (sym (H.ε _))

        γ' : l₀ A.∘ m .from ≡ m' .from A.∘ l
        γ' = A.iso→monic m' _ _ $ A.extendl (H.injective (H.swap γ))
                               ·· A.elimr (m .invl)
                               ·· A.insertl (m' .invl)

        δ : g₀ C.∘ k a h .to ≡ k a' h' .to C.∘ F.₁ l
        δ = C.pullr ( C.pullr refl ·· ap₂ C._∘_ refl (C.pushl α)
                   ·· C.pulll refl ∙ C.elimr (k a h .invr))
          ·· ap₂ C._∘_ refl (F.weave γ')
          ·· C.pulll (C.pushl (sym (kcomm _ _ _ (H.ε-lswizzle (h' .invl))))
              ∙ C.elimr (F.annihilate (m' .invl)))

      Homs-pt : Homs f
      Homs-pt = g₀ , λ a h a' h' l w → sym (δ a h a' h' l w)

      Homs-prop' : (h' : Homs f) → h' .fst ≡ g₀
      Homs-prop' (g₁ , w) = C.iso→epic (k a₀ h₀) _ _
        (sym (δ a₀ h₀ a₀' h₀' l₀ p ∙ w a₀ h₀ a₀' h₀' l₀ p))

    Homs-contr' : ∀ {b b'} (f : B.Hom b b') → ∥ is-contr (Homs f) ∥
    Homs-contr' {b = b} {b'} f = do
      (a₀ , h)   ← H-eso b
      (a₀' , h') ← H-eso b'
      inc (contr (Homs-pt f a₀ h a₀' h') λ h' → Σ-prop-path!
        (sym (Homs-prop' f _ _ _ _ h')))

    Homs-contr : ∀ {b b'} (f : B.Hom b b') → is-contr (Homs f)
    Homs-contr f = ∥-∥-out! (Homs-contr' f)

    G₁ : ∀ {b b'} → B.Hom b b' → C.Hom (G₀ b) (G₀ b')
    G₁ f = Homs-contr f .centre .fst

    module G∘ {x y z} (f : B.Hom y z) (g : B.Hom x y)
              {ax ay az} (hx : H.₀ ax B.≅ x) (hy : H.₀ ay B.≅ y)
              (hz : H.₀ az B.≅ z) where

      af : A.Hom ay az
      af = H.from (hz .from B.∘ f B.∘ hy .to)

      ag : A.Hom ax ay
      ag = H.from (hy .from B.∘ g B.∘ hx .to)

      h' : H.₁ (af A.∘ ag) ≡ hz .from B.∘ f B.∘ g B.∘ hx .to
      h' = H.ε-expand refl ∙ B.pullr (B.cancel-inner (hy .invl))

      commutes : G₁ (f B.∘ g) ≡ G₁ f C.∘ G₁ g
      commutes = C.iso→epic (k ax hx) _ _ $
          sym (Homs-contr (f B.∘ g) .centre .snd ax hx az hz (af A.∘ ag)
                (ap₂ B._∘_ refl h' ·· B.cancell (hz .invl) ·· B.pulll refl))
        ∙ sym ( C.pullr (sym (Homs-contr g .centre .snd ax hx ay hy ag
                  (H.ε-lswizzle (hy .invl))))
              ∙ C.pulll (sym (Homs-contr f .centre .snd ay hy az hz af
                  (H.ε-lswizzle (hz .invl))))
              ∙ F.pullr refl)

In this manner, the assignment of object candidates and morphism candidates fits together into a functor $G:\mathcal{B}\to \mathcal{C}\text{.}$ After finishing this, we have to show that $GH=F\text{.}$ But the compatibility data which we have used to uniquely characterise $G\text{…}$ uniquely characterises $G\text{,}$ after all, and it does so as composing with $H$ to give $F$.

    G : Functor B C
    G .F₀ b = G₀ b
    G .F₁ f = G₁ f

    G .F-id = ap fst $ Homs-contr B.id .paths $ C.id , λ a h a' h' l w →
      sym (C.idl _ ∙ sym (kcomm (a , h) (a' , h') l (w ∙ B.idl _)))

Note that we proved⁷ that $G_1$ is functorial given choices of essential fibres of all three objects involved in the composition. Since we’re showing an equality in a set — a proposition — these choices don’t matter, so we can use essential surjectivity of $H\text{.}$

    G .F-∘ {x} {y} {z} f g = ∥-∥-out! do
      (ax , hx) ← H-eso x
      (ay , hy) ← H-eso y
      (az , hz) ← H-eso z
      inc (G∘.commutes f g hx hy hz)

To use the unique charactersation of $G$ as “the functor satisfying $GH=F$”, observe: for any $x:\mathcal{A}\text{,}$ the object $F(x)$ can be made into an object candidate over $H(x)\text{,}$ and since the type of object candidates is a proposition, our candidate $F(x)$ is identical to the value of $GH(x)\text{.}$ That’s half of $GH=F$ established right off the bat!

    module _ (x : A.Ob) where
      hf-obs : Obs (H.₀ x)
      hf-obs .fst = F.F₀ x
      hf-obs .snd .fst a h = F-map-iso F (H.iso.from h)
      hf-obs .snd .snd (a , h) (a' , h') f α = F.collapse (H.inv∘l α)

      abstract
        objp : G₀ (H.₀ x) ≡ F.₀ x
        objp = ap fst $ summon {H.₀ x} (H-eso _) .paths hf-obs

        kp : (a : A.Ob) (h : H.₀ a B.≅ H.₀ x)
           → PathP (λ i → F.₀ a C.≅ objp i) (k a h) (hf-obs .snd .fst a h)
        kp a h = ap (λ e → e .snd .fst a h)
          (summon {H.₀ x} (H-eso (H.₀ x)) .paths hf-obs)

Over that identification, we can show that, for any $f:x\to y$ in $\mathcal{A}\text{,}$ the value $F(f)$ is also a candidate for the morphism $GH(f)\text{,}$ so these are also identical. This proof is a bit hairier, because $F(f)$ only has the right type if we adjust it by the proof that $GH(x)=F(x)\text{:}$ we have to transport $F(f)\text{,}$ and then as punishment for our hubris, invoke a lot of technical lemmas about the characterisation of PathP in the morphism spaces of (pre)categories.

    module _ {x y} (f : A.Hom x y) where
      hom' : Homs (H.₁ f)
      hom' .fst = transport (λ i → C.Hom (objp x (~ i)) (objp y (~ i))) (F.₁ f)
      hom' .snd a h a' h' l w = sym $
        C.pushl (Hom-transport C (sym (objp x)) (sym (objp y)) (F.₁ f))
        ·· ap₂ C._∘_ refl
          ( C.pullr (from-pathp-from C (objp x) (λ i → kp x a h i .to))
          ∙ F.weave (H.ε-twist (sym w)))
        ·· C.pulll (from-pathp-to C (sym (objp y)) λ i → kp y a' h' (~ i) .to)

      homp : transport (λ i → C.Hom (objp x (~ i)) (objp y (~ i))) (F.₁ f)
           ≡ Homs-contr (H.₁ f) .centre .fst
      homp = ap fst $ sym $ Homs-contr (H.₁ f) .paths hom'

    correct : G F∘ H ≡ F
    correct = Functor-path objp λ {x} {y} f → symP
      {A = λ i → C.Hom (objp x (~ i)) (objp y (~ i))} $
      to-pathp (homp f)

Since we’ve shown that $GH=F\text{,}$ so in particular $GH\cong F\text{,}$ we’ve now put together proofs that $-\circ H$ is fully faithful and, since the construction above works for any $F\text{,}$ essentially surjective. Even better, since we’ve actually constructed a functor $G\text{,}$ we’ve shown that $-\circ H$ is split essentially surjective! Since $[-,\mathcal{C}]$ is univalent whenever $\mathcal{C}$ is, the splitting would be automatic, but this is a nice strengthening.

  weak-equiv→pre-equiv : is-equivalence {C = Cat[ B , C ]} (precompose H)
  weak-equiv→pre-equiv = ff+split-eso→is-equivalence {F = precompose H}
    (eso-full→pre-ff H H-eso λ g → inc (H.from g , H.ε g))
    λ F → G F , path→iso (correct F)

And since a functor is an equivalence of categories iff. it is an isomorphism of categories, we also have that the rule sending $F$ to its $G$ is an equivalence of types.

  weak-equiv→pre-iso : is-precat-iso {C = Cat[ B , C ]} (precompose H)
  weak-equiv→pre-iso = is-equivalence→is-precat-iso (precompose H) weak-equiv→pre-equiv
    (Functor-is-category c-cat)
    (Functor-is-category c-cat)

Restating the result that $-\circ H$ acts on objects as an equivalence of types, we have the following result: If $R:\mathcal{C}\to {\mathcal{C}}^{+}$ is a weak equivalence (a fully faithful and essentially surjective functor), then for any category $\mathcal{D}$ and functor $G:\mathcal{C}\to \mathcal{D}\text{,}$ there is a contractible space(!) of extensions $H:{\mathcal{C}}^{+}\to \mathcal{D}$ which factor $G$ through $F\text{.}$

weak-equiv→reflection
  : (F : Functor C C⁺) → is-eso F → is-fully-faithful F
  → {D : Precategory o ℓ} → is-category D
  → (G : Functor C D)
  → is-contr (Σ (Functor C⁺ D) λ H → H F∘ F ≡ G)
weak-equiv→reflection F F-eso F-ff D-cat G =
  weak-equiv→pre-iso F F-eso F-ff D-cat
    .is-precat-iso.has-is-iso .is-eqv G

Note that this is only half of the point of the Rezk completion: we would also like for ${\mathcal{C}}^{+}$ to be univalent, but that is not necessary for $D$ to think that precomposition with $F$ is an isomorphism.