open import Cat.Functor.FullSubcategory
open import Cat.Functor.Properties
open import Cat.Instances.Functor
open import Cat.Instances.Sets
open import Cat.Functor.Hom
open import Cat.Prelude

open import Data.Image

import Cat.Functor.Reasoning.FullyFaithful as Ffr
import Cat.Reasoning as Cr

module Cat.Univalent.Rezk where

private variable
  o h o' h' : Level
open Precategory
open Functor

The Rezk completion🔗

In the same way that we can freely complete a proset into a poset, it is possible to, in a universal way, replace any precategory $\mathcal{A}$ by a category $\hat{\mathcal{A}}\text{,}$ such that there is a weak equivalence (a fully faithful, essentially surjective functor) $\mathcal{A}\to \hat{\mathcal{A}}\text{,}$ such that any map from $\mathcal{A}$ to a univalent category $\mathcal{C}$ factors uniquely through $\hat{\mathcal{A}}\text{.}$

The construction is essentially piecing together a handful of pre-existing results: The univalence principle for $n\text{-types}$ implies that Sets is a univalent category, and functor categories with univalent codomain are univalent; The Yoneda lemma implies that any precategory $\mathcal{A}$ admits a full inclusion into $[{\mathcal{A}}^{\mathrm{op}},\mathbf{Sets}]\text{,}$ and full subcategories of univalent categories are univalent — so, like Grothendieck cracking the nut, the sea of theory has risen to the point where our result is trivial:

module Rezk-large (A : Precategory o h) where
  Rezk-completion : Precategory (o ⊔ lsuc h) (o ⊔ h)
  Rezk-completion = Full-inclusion→Full-subcat {F = よ A} (よ-is-fully-faithful A)

  Rezk-completion-is-category : is-category Rezk-completion
  Rezk-completion-is-category =
    Restrict-is-category _ (λ _ → squash)
      (Functor-is-category Sets-is-category)

  Complete : Functor A Rezk-completion
  Complete = Ff-domain→Full-subcat {F = よ A} (よ-is-fully-faithful A)

  Complete-is-ff : is-fully-faithful Complete
  Complete-is-ff = is-fully-faithful-domain→Full-subcat
      {F = よ _} (よ-is-fully-faithful _)

  Complete-is-eso : is-eso Complete
  Complete-is-eso = is-eso-domain→Full-subcat {F = よ _} (よ-is-fully-faithful _)

However, this construction is a bit disappointing, because we’ve had to pass to a larger universe than the one we started with. If originally we had $\mathcal{A}$ with objects living in a universe $o$ and homs in $h\text{,}$ we now have $\hat{\mathcal{A}}$ with objects living in $o\bigsqcup (1+h)\text{.}$

It’s unavoidable that the objects in $\hat{\mathcal{A}}$ will live in an universe $\hat{o}$ satisfying $(o\bigsqcup h)\le \hat{o}\text{,}$ since we want their identity type to be equivalent to something living in $h\text{,}$ but going up a level is unfortunate. However, it’s also avoidable!

Since $\mathrm{PSh}(\mathcal{A})$ is a category, isomorphism is an identity system on its objects, which lives at the level of its morphisms — $o\bigsqcup h$ — rather than of its objects, $o\bigsqcup (1+h)\text{.}$ Therefore, using the construction of small images, we may take $\mathrm{im}{よ}_{\mathcal{A}}$ to be a $o\bigsqcup h\text{-type!}$

module _ (A : Precategory o h) where
  private
    PSh[A] = PSh h A
    module PSh[A] = Precategory PSh[A]

    PSh[A]-is-cat : is-category PSh[A]
    PSh[A]-is-cat = Functor-is-category Sets-is-category

    module よim = Replacement PSh[A]-is-cat (よ₀ A)

  Rezk-completion : Precategory (o ⊔ h) (o ⊔ h)
  Rezk-completion .Ob          = よim.Image
  Rezk-completion .Hom x y     = よim.embed x => よim.embed y
  Rezk-completion .Hom-set _ _ = PSh[A].Hom-set _ _
  Rezk-completion .id    = PSh[A].id
  Rezk-completion ._∘_   = PSh[A]._∘_
  Rezk-completion .idr   = PSh[A].idr
  Rezk-completion .idl   = PSh[A].idl
  Rezk-completion .assoc = PSh[A].assoc

Our resized Rezk completion $\hat{\mathcal{A}}$ factors the Yoneda embedding ${よ}_{\mathcal{A}}$ as a functor

where the first functor is a weak equivalence, and the second functor is fully faithful. Let’s first define the functors:

  complete : Functor A Rezk-completion
  complete .F₀   = よim.inc
  complete .F₁   = よ A .F₁
  complete .F-id = よ A .F-id
  complete .F-∘  = よ A .F-∘

  Rezk↪PSh : Functor Rezk-completion (PSh h A)
  Rezk↪PSh .F₀      = よim.embed
  Rezk↪PSh .F₁ f    = f
  Rezk↪PSh .F-id    = refl
  Rezk↪PSh .F-∘ _ _ = refl

From the existence of the second functor, we can piece together pre-existing lemmas about the image and about identity systems in general to show that this resized Rezk completion is also a category: We can pull back the identity system on $\mathrm{PSh}(\mathcal{A})$ to one on $\hat{\mathcal{A}}\text{,}$ since we know of a (type-theoretic) embedding between their types of objects.

That gives us an identity system which is slightly off, that of “$\mathrm{PSh}(\mathcal{A})\text{-isomorphisms}$ on the image of the functor $\hat{\mathcal{A}}\hookrightarrow \mathrm{PSh}(\mathcal{A})$”, but since we know that this functor is fully faithful, that’s equivalent to what we want.

  private module Rezk↪PSh = Ffr Rezk↪PSh id-equiv

  abstract
    Rezk-completion-is-category : is-category Rezk-completion
    Rezk-completion-is-category =
      transfer-identity-system
        (pullback-identity-system
          (Functor-is-category Sets-is-category)
          (よim.embed , よim.embed-is-embedding))
        (λ x y → Rezk↪PSh.iso-equiv e⁻¹)
        λ x → trivial!

It remains to show that the functor $\mathcal{A}\to \hat{\mathcal{A}}$ is a weak equivalence. It’s fully faithful because the Yoneda embedding is, and it’s essentially surjective because it’s literally surjective-on-objects.

  complete-is-ff : is-fully-faithful complete
  complete-is-ff = よ-is-fully-faithful A

  complete-is-eso : is-eso complete
  complete-is-eso x = do
    t ← よim.inc-is-surjective x
    pure (t .fst , path→iso (t .snd))