open import Cat.Diagram.Pullback.Properties
open import Cat.Displayed.Cocartesian.Weak
open import Cat.Displayed.Cocartesian
open import Cat.Displayed.Univalence
open import Cat.Displayed.Cartesian
open import Cat.Instances.Functor
open import Cat.Diagram.Pullback
open import Cat.Diagram.Product
open import Cat.Displayed.Fibre
open import Cat.Displayed.Base
open import Cat.Diagram.Image
open import Cat.Prelude

import Cat.Reasoning as Cr

module Cat.Displayed.Instances.Subobjects
  {o ℓ} (B : Precategory o ℓ)
  where

open Cr B
open Displayed

The fibration of subobjects🔗

Given a base category $\mathcal{B}\text{,}$ we can define the displayed category of subobjects over $\mathcal{B}\text{.}$ This is, in essence, a restriction of the codomain fibration of $\mathcal{B}\text{,}$ but with our attention restricted to the monomorphisms $a\hookrightarrow b$ rather than arbitrary maps $a\to b\text{.}$

record Subobject (y : Ob) : Type (o ⊔ ℓ) where
  no-eta-equality
  field
    {domain} : Ob
    map   : Hom domain y
    monic : is-monic map

open Subobject public

To make formalisation smoother, we define our own version of displayed morphisms in the subobject fibration, rather than reusing those of the fundamental self-indexing. The reason for this is quite technical: the type of maps in the self-indexing is only dependent (the domains and) the morphisms being considered, meaning nothing constrains the proofs that these are monomorphisms, causing unification to fail at the determining the full Subobjects involved.

record ≤-over {x y} (f : Hom x y) (a : Subobject x) (b : Subobject y) : Type ℓ where
  no-eta-equality
  field
    map : Hom (a .domain) (b .domain)
    sq : f ∘ Subobject.map a ≡ Subobject.map b ∘ map

open ≤-over public

We will denote the type of maps $x^{\prime }{\to }_f{y}^{\prime }$ in the subobject fibration by $x^{\prime }{\le }_f{y}^{\prime }\text{,}$ since there is at most one such map: if $g,h$ satisfy $y^{\prime }g=f{x}^{\prime }=y^{\prime }h\text{,}$ then, since $y^{\prime }$ is a mono, $g=h\text{.}$

≤-over-is-prop
  : ∀ {x y} {f : Hom x y} {a : Subobject x} {b : Subobject y}
  → (p q : ≤-over f a b)
  → p ≡ q
≤-over-is-prop {f = f} {a} {b} p q = path where
  maps : p .map ≡ q .map
  maps = b .monic (p .map) (q .map) (sym (p .sq) ∙ q .sq)

  path : p ≡ q
  path i .map = maps i
  path i .sq = is-prop→pathp (λ i → Hom-set _ _ (f ∘ a .map) (b .map ∘ maps i)) (p .sq) (q .sq) i

instance
  H-Level-≤-over
    : ∀ {x y} {f : Hom x y} {a : Subobject x} {b : Subobject y} {n}
    → H-Level (≤-over f a b) (suc n)
  H-Level-≤-over = prop-instance ≤-over-is-prop

Setting up the displayed category is now nothing more than routine verification: the identity map satisfies $\mathrm{id}a=a\mathrm{id}\text{,}$ and commutative squares can be pasted together.

Subobjects : Displayed B (o ⊔ ℓ) ℓ
Subobjects .Ob[_] y = Subobject y
Subobjects .Hom[_]  = ≤-over
Subobjects .Hom[_]-set f a b = hlevel 

Subobjects .id' .map = id
Subobjects .id' .sq  = id-comm-sym

Subobjects ._∘'_ α β .map = α .map ∘ β .map
Subobjects ._∘'_ α β .sq  = pullr (β .sq) ∙ extendl (α .sq)

Subobjects .idr' _       = prop!
Subobjects .idl' _       = prop!
Subobjects .assoc' _ _ _ = prop!

open is-weak-cocartesian-fibration
open Weak-cocartesian-lift
open Cartesian-fibration
open is-weak-cocartesian
open Cartesian-lift
open is-cartesian
open Pullback

As a fibration🔗

By exactly the same construction as for the fundamental self-indexing, if $\mathcal{B}$ has pullbacks, the displayed category we have built is actually a fibration. The construction is slightly simpler now that we have no need to worry about uniqueness, but we can remind ourselves of the universal property:

On the first stage, we are given the data in black: we can complete an open span $y^{\prime }\hookrightarrow y\stackrel{f}{\leftarrow }x$ to a Cartesian square (in blue) by pulling $y^{\prime }$ back along $f\text{;}$ this base change remains a monomorphism. Now given the data in red, we verify that the dashed arrow exists, which is enough for its uniqueness.

Subobject-fibration
  : has-pullbacks B
  → Cartesian-fibration Subobjects
Subobject-fibration pb .has-lift f y' = l where
  it : Pullback _ _ _
  it = pb (y' .map) f
  l : Cartesian-lift Subobjects f y'

  -- The blue square:
  l .x' .domain = it .apex
  l .x' .map    = it .p₂
  l .x' .monic  = is-monic→pullback-is-monic (y' .monic) (it .has-is-pb)
  l .lifting .map = it .p₁
  l .lifting .sq  = sym (it .square)

  -- The dashed red arrow:
  l .cartesian .universal {u' = u'} m h' = λ where
    .map → it .Pullback.universal (sym (h' .sq) ∙ sym (assoc f m (u' .map)))
    .sq  → sym (it .p₂∘universal)
  l .cartesian .commutes _ _ = prop!
  l .cartesian .unique _ _   = prop!

As a (weak) cocartesian fibration🔗

If $\mathcal{B}$ has an image factorisation for every morphism, then its fibration of subobjects is a weak cocartesian fibration. By a general fact, if $\mathcal{B}$ also has pullbacks, then $\mathrm{Sub}(-)$ is a cocartesian fibration.

Subobject-weak-opfibration
  : (∀ {x y} (f : Hom x y) → Image B f)
  → is-weak-cocartesian-fibration Subobjects
Subobject-weak-opfibration ims .weak-lift f x' = l where
  module im = Image B (ims (f ∘ x' .map))

To understand this result, we remind ourselves of the universal property of an image factorisation for $f:a\to b\text{:}$ It is the initial subobject through with $f$ factors. That is to say, if $m:\mathrm{Sub}(b)$ is another subobject, and $f=me$ for some map $e:a\to m\text{,}$ then $m\le \mathrm{im}f\text{.}$ Summarised diagrammatically, the universal property of an image factorisation looks like a kite:

Now compare this with the universal property required of a weak co-cartesian lift:

By smooshing the corner $x^{\prime }\hookrightarrow x\to y$ together (i.e., composing $x^{\prime }$ and $f\text{),}$ we see that this is exactly the kite-shaped universal property of $\mathrm{im}f{x}^{\prime }\text{.}$

  l : Weak-cocartesian-lift Subobjects f x'
  l .y' .domain = im.Im
  l .y' .map    = im.Im→codomain
  l .y' .monic  = im.Im→codomain-is-M

  l .lifting .map = im.corestrict
  l .lifting .sq  = sym im.image-factors

  l .weak-cocartesian .universal {x' = y'} h .map = im.universal _ (y' .monic) (h .map) (sym (h .sq))
  l .weak-cocartesian .universal h .sq = idl _ ∙ sym im.universal-factors

  l .weak-cocartesian .commutes g' = prop!
  l .weak-cocartesian .unique _ _  = prop!

The aforementioned general fact says that any cartesian and weak cocartesian fibration must actually be a full opfibration.

Subobject-opfibration
  : (∀ {x y} (f : Hom x y) → Image B f)
  → (pb : has-pullbacks B)
  → Cocartesian-fibration Subobjects
Subobject-opfibration images pb = cartesian+weak-opfibration→opfibration _
  (Subobject-fibration pb)
  (Subobject-weak-opfibration images)

Subobjects over a base🔗

We define the category $\mathrm{Sub}(y)$ of subobjects of $y$ as a fibre of the subobject fibration. However, we use a purpose-built transport function to cut down on the number of coherences required to work with $\mathrm{Sub}(y)$ at use-sites.

Sub : Ob → Precategory (o ⊔ ℓ) ℓ
Sub y = Fibre' Subobjects y re coh where
  re : ∀ {a b} → ≤-over (id ∘ id) a b → ≤-over id a b
  re x .map = x .map
  re x .sq  = ap₂ _∘_ (introl refl) refl ∙ x .sq

  abstract
    coh : ∀ {a b} (f : ≤-over (id ∘ id) a b) → re f ≡ transport (λ i → ≤-over (idl id i) a b) f
    coh f = prop!

module Sub {y} = Cr (Sub y)

_≤ₘ_ : ∀ {y} (a b : Subobject y) → Type _
_≤ₘ_ = ≤-over id

≤ₘ→mono : ∀ {y} {a b : Subobject y} → a ≤ₘ b → a .domain ↪ b .domain
≤ₘ→mono x .mor = x .map
≤ₘ→mono {a = a} x .monic g h α = a .monic g h $
  a .map ∘ g      ≡⟨ ap (_∘ g) (introl refl ∙ x .sq) ∙ pullr refl ⟩≡
  _ ∘ x .map ∘ g  ≡⟨ ap₂ _∘_ refl α ⟩≡
  _ ∘ x .map ∘ h  ≡⟨ pulll (sym (x .sq) ∙ idl _) ⟩≡
  a .map ∘ h      ∎

cutₛ : ∀ {x y} {f : Hom x y} → is-monic f → Subobject y
cutₛ x .domain = _
cutₛ x .map    = _
cutₛ x .monic  = x

Sub-antisym
  : ∀ {y} {a b : Subobject y}
  → a ≤ₘ b
  → b ≤ₘ a
  → a Sub.≅ b
Sub-antisym f g = Sub.make-iso f g prop! prop!

Sub-path
  : ∀ {y} {a b : Subobject y}
  → (p : a .domain ≡ b .domain)
  → PathP (λ i → Hom (p i) y) (a .map) (b .map)
  → a ≡ b
Sub-path p q i .domain = p i
Sub-path p q i .map = q i
Sub-path {a = a} {b = b} p q i .monic {c} =
  is-prop→pathp (λ i → Π-is-hlevel³  λ (g h : Hom c (p i)) (_ : q i ∘ g ≡ q i ∘ h) → Hom-set _ _ g h)
    (a .monic) (b .monic) i

Fibrewise cartesian structure🔗

Since products in slice categories are given by pullbacks, and pullbacks preserve monomorphisms, if $\mathcal{B}$ has pullbacks, then $\mathrm{Sub}(y)$ has products, regardless of what $y$ is.

Sub-products
  : ∀ {y}
  → has-pullbacks B
  → has-products (Sub y)
Sub-products {y} pb a b = prod where
  it = pb (a .map) (b .map)

  prod : Product (Sub y) a b
  prod .Product.apex .domain = it .apex
  prod .Product.apex .map = a .map ∘ it .p₁
  prod .Product.apex .monic = monic-∘
    (a .monic)
    (is-monic→pullback-is-monic (b .monic) (rotate-pullback (it .has-is-pb)))

  prod .Product.π₁ .map = it .p₁
  prod .Product.π₁ .sq  = idl _

  prod .Product.π₂ .map = it .p₂
  prod .Product.π₂ .sq  = idl _ ∙ it .square

  prod .Product.has-is-product .is-product.⟨_,_⟩ q≤a q≤b .map =
    it .Pullback.universal {p₁' = q≤a .map} {p₂' = q≤b .map} (sym (q≤a .sq) ∙ q≤b .sq)
  prod .Product.has-is-product .is-product.⟨_,_⟩ q≤a q≤b .sq =
    idl _ ∙ sym (pullr (it .p₁∘universal) ∙ sym (q≤a .sq) ∙ idl _)
  prod .Product.has-is-product .is-product.π₁∘⟨⟩ = prop!
  prod .Product.has-is-product .is-product.π₂∘⟨⟩ = prop!
  prod .Product.has-is-product .is-product.unique _ _ = prop!

Univalence🔗

Since identity of $m,n:\mathrm{Sub}(y)$ is given by identity of they underlying objects and identity-over of the corresponding morphisms, if $\mathcal{B}$ is univalent, we can conclude that $\mathrm{Sub}(y)$ is, too. Since $\mathrm{Sub}(y)$ is always thin, we can summarise the situation by saying that $\mathrm{Sub}(y)$ is a partial order if $\mathcal{B}$ is univalent.

Sub-is-category : ∀ {y} → is-category B → is-category (Sub y)
Sub-is-category b-cat .to-path {a} {b} x =
  Sub-path
    (b-cat .to-path i)
    (Univalent.Hom-pathp-refll-iso b-cat (sym (x .Sub.from .sq) ∙ idl _))
  where
    i : a .domain ≅ b .domain
    i = make-iso (x .Sub.to .map) (x .Sub.from .map) (ap map (Sub.invl x)) (ap map (Sub.invr x))
Sub-is-category b-cat .to-path-over p =
  Sub.≅-pathp refl _ prop!