open import Cat.Diagram.Equaliser.Kernel
open import Cat.Instances.Shape.Terminal
open import Cat.Functor.FullSubcategory
open import Cat.Diagram.Initial
open import Cat.Instances.Comma
open import Cat.Instances.Slice
open import Cat.Diagram.Image
open import Cat.Abelian.Base
open import Cat.Prelude

open /-Obj
open /-Hom
open ↓Obj
open ↓Hom

module Cat.Abelian.Images {o ℓ} {C : Precategory o ℓ} (A : is-abelian C) where
open is-abelian A

Images in abelian categories🔗

Let $f:A\to B$ be a morphism in an abelian category $\mathcal{A}\text{,}$ which (by definition) admits a canonical decomposition as

where the map $p$ is epic, $i$ is monic, and the indicated isomorphism arises from $f$ in a canonical way, using the universal properties of kernels and cokernels. What we show in this section is that the arrow $\ker (\mathrm{coker}f)\hookrightarrow B$ is an image factorisation for $f\text{:}$ It is the largest monomorphism through which $f$ factors. Since this construction does not depend on any specificities of $f\text{,}$ we conclude that every map in an abelian category factors as a regular epi followed by a regular mono.

The image🔗

images : ∀ {A B} (f : Hom A B) → Image C f
images f = im where
  the-img : ↓Obj (const! (cut f)) Forget-full-subcat
  the-img .x = tt
  the-img .y .object = cut (Ker.kernel (Coker.coeq f))
  the-img .y .witness {c} = kernels-are-subobjects C ∅ _ (Ker.has-is-kernel _)

Break $f$ down as an epi $p:A\twoheadrightarrow \ker (\mathrm{coker}f)$ followed by a mono $i:\ker (\mathrm{coker}f)\hookrightarrow B\text{.}$ We can take the map $i$ as the “image” subobject. We must provide a map filling the dotted line in

but this is the epimorphism $p$ in our factorisation. More precisely, it’s the epimorphism $p$ followed by the isomorphism $f^{\prime }$ in the decomposition

  the-img .map ./-Hom.map = decompose f .fst ∘ Coker.coeq _
  the-img .map ./-Hom.commutes = pulll (Ker.factors _) ∙ Coker.factors _

Universality🔗

Suppose that we’re given another decomposition of $f$ as

and we wish to construct a map $g:i^{\prime }\le i$¹, hence a map $\mathrm{im}f\to X$ such that the triangle

commutes.

  im : Image C f
  im .Initial.bot = the-img
  im .Initial.has⊥ other = contr factor unique where
    factor : ↓Hom (const! (cut f)) Forget-full-subcat the-img other
    factor .α = tt
    factor .β ./-Hom.map =
        Coker.universal (Ker.kernel f) {e' = other .map .map} path
      ∘ coker-ker≃ker-coker f .is-invertible.inv

Observe that by the universal property of $\mathrm{coker}(\ker f)$², if we have a map $q:A\to X$ such that $0=q\ker f\text{,}$ then we can obtain a (unique) map $\mathrm{coker}(\ker f)\to X$ s.t. the triangle above commutes!

      where abstract
        path : other .map .map ∘ 0m ≡ other .map .map ∘ kernel f .Kernel.kernel
        path =
          other .y .witness _ _ $ sym $
                pulll (other .map .commutes)
            ·· Ker.equal f
            ·· ∅.zero-∘r _
            ·· 0m-unique
            ·· sym (ap₂ _∘_ refl ∘-zero-r ∙ ∘-zero-r)

To satisfy that equation, observe that since $i^{\prime }$ is monic, it suffices to show that $i^{\prime }0=i^{\prime }q\ker f\text{,}$ but we have assumed that $i^{\prime }q=f\text{,}$ and $f\ker f=0$ by the definition of kernel. Some tedious isomorphism-algebra later, we have shown that $\ker (\mathrm{coker}f)\hookrightarrow B$ is the image of $f\text{.}$

    factor .β ./-Hom.commutes = invertible→epic (coker-ker≃ker-coker f) _ _ $
      Coker.unique₂ (Ker.kernel f)
        (sym (Ker.equal f ∙ ∅.zero-∘r _ ∙ 0m-unique ∙ sym ∘-zero-r))
        (ap₂ _∘_ ( sym (assoc _ _ _)
                        ∙ ap₂ _∘_ refl (cancelr
                          (coker-ker≃ker-coker f .is-invertible.invr))) refl
              ∙ pullr (Coker.factors _) ∙ other .map .commutes)
        (sym (decompose f .snd ∙ assoc _ _ _))
    factor .sq = /-Hom-path $ sym $ other .y .witness _ _ $
      pulll (factor .β .commutes)
      ∙ the-img .map .commutes
      ·· sym (other .map .commutes)
      ·· ap (other .y .object .map ∘_) (intror refl)

    unique : ∀ x → factor ≡ x
    unique x = ↓Hom-path _ _ refl $ /-Hom-path $ other .y .witness _ _ $
      sym (x .β .commutes ∙ sym (factor .β .commutes))