open import Cat.Bi.Base
open import Cat.Prelude

import Cat.Diagram.Monad as Cat
import Cat.Reasoning as Cr

module Cat.Bi.Diagram.Monad  where

open _=>_

module _ {o ℓ ℓ'} (B : Prebicategory o ℓ ℓ') where
  private module B = Prebicategory B

Monads in a bicategory🔗

Recall that a monad on a category $\mathcal{C}$ consists of a functor $M:\mathcal{C}\to \mathcal{C}$ and natural transformations $\mu :MM\Rightarrow M\text{,}$ $\eta :\mathrm{Id}\Rightarrow M\text{.}$ While the words “functor” and “natural transformation” are specific to the setup where $\mathcal{C}$ is a category, if we replace those with “1-cell” and “2-cell”, then the definition works in any bicategory!

  record Monad (a : B.Ob) : Type (ℓ ⊔ ℓ') where
    field
      M : a B.↦ a
      μ : (M B.⊗ M) B.⇒ M
      η : B.id B.⇒ M

The setup is, in a sense, a lot more organic when phrased in an arbitrary bicategory: Rather than dealing with the specificities of natural transformations and the category $\mathcal{C}\text{,}$ we abstract all of that away into the setup of the bicategory $\mathbf{B}\text{.}$ All we need is that the multiplication $\mu$ be compatible with the associator $\alpha \text{,}$ and the unit $\eta$ must be appropriately compatible with the left and right unitors $\lambda ,\rho \text{.}$

      μ-assoc : μ B.∘ (M B.▶ μ) ≡ μ B.∘ (μ B.◀ M) B.∘ B.α← M M M
      μ-unitr : μ B.∘ (M B.▶ η) ≡ B.ρ← M
      μ-unitl : μ B.∘ (η B.◀ M) ≡ B.λ← M

We can draw these compatibility conditions as pretty commutative diagrams. The commutative altar (on top) indicates associativity of multiplication, or more abstractly, compatibility of the multiplication with the associator. The commutative upside-down triangle indicates mutual compatibility of the multiplication and unit with the unitors.

In Cat🔗

To prove that this is an actual generalisation of the 1-categorical notion, we push some symbols around and prove that a monad in the bicategory $\mathbf{Cat}$ is the same thing as a monad on some category. Things are set up so that this is almost definitional, but the compatibility paths have to be adjusted slightly. Check it out below:

module _ {o ℓ} {C : Precategory o ℓ} where
  open Cat.Monad
  open Monad
  private module C = Cr C

  Bicat-monad→monad : Monad (Cat _ _) C → Cat.Monad C
  Bicat-monad→monad monad = monad' where
    private module M = Monad monad

    monad' : Cat.Monad C
    monad' .M = M.M
    monad' .unit = M.η
    monad' .mult = M.μ
    monad' .left-ident {x} =
        ap (M.μ .η x C.∘_) (C.intror refl)
      ∙ M.μ-unitr ηₚ x
    monad' .right-ident {x} =
        ap (M.μ .η x C.∘_) (C.introl (M.M .Functor.F-id))
      ∙ M.μ-unitl ηₚ x
    monad' .mult-assoc {x} =
        ap (M.μ .η x C.∘_) (C.intror refl)
     ·· M.μ-assoc ηₚ x
     ·· ap (M.μ .η x C.∘_) (C.elimr refl ∙ C.eliml (M.M .Functor.F-id))

  Monad→bicat-monad : Cat.Monad C → Monad (Cat _ _) C
  Monad→bicat-monad monad = monad' where
    private module M = Cat.Monad monad

    monad' : Monad (Cat _ _) C
    monad' .M = M.M
    monad' .μ = M.mult
    monad' .η = M.unit
    monad' .μ-assoc = ext λ _ →
        ap (M.μ _ C.∘_) (C.elimr refl)
     ·· M.mult-assoc
     ·· ap (M.μ _ C.∘_) (C.introl (M.M-id) ∙ C.intror refl)
    monad' .μ-unitr = ext λ _ →
        ap (M.μ _ C.∘_) (C.elimr refl)
      ∙ M.left-ident
    monad' .μ-unitl = ext λ _ →
        ap (M.μ _ C.∘_) (C.eliml M.M-id)
      ∙ M.right-ident