open import Algebra.Group.NAry
open import Algebra.Group.Ab

open import Cat.Diagram.Coproduct.Indexed
open import Cat.Diagram.Product.Indexed
open import Cat.Diagram.Limit.Finite
open import Cat.Diagram.Equaliser
open import Cat.Abelian.Base
open import Cat.Diagram.Zero
open import Cat.Prelude hiding (_-_ ; _+_)

open import Data.Id.Base
open import Data.Dec
open import Data.Fin

import Cat.Abelian.NAry

module Cat.Abelian.Limits {o ℓ} {C : Precategory o ℓ} where

Limits🔗

Recall that every pre-abelian category admits kernels and cokernels, and is also additive, so it additionally has products and coproducts¹. It sounds like we’re missing some finite limits (dually, missing some finite colimits), but it turns out that this is enough: We can construct the equaliser of $f,g:A\to B$ as $\ker (f-g)$ — whence the name difference kernel!

The calculation is straightforward: To map out of $\ker f\text{,}$ we must have $(f{e}^{\prime }-g{e}^{\prime })=0\text{,}$ but this is immediate assuming that $f{e}^{\prime }=g{e}^{\prime }$ — an assumption we have to map out of $\mathrm{eq}(f,g)\text{.}$ Similarly, to show that $f\ker (f-g)=g\ker (f-g)\text{,}$ we calculate

module _ (A : is-pre-abelian C) where
  open is-pre-abelian A
  difference-kernel
    : ∀ {A B} {f g : Hom A B}
    → is-equaliser C f g (Ker.kernel (f - g))
  difference-kernel {f = f} {g} = equ where
    open is-equaliser
    equ : is-equaliser C f g (Ker.kernel (f - g))
    equ .equal = zero-diff $
      (f ∘ Ker.kernel (f - g)) - (g ∘ Ker.kernel (f - g)) ≡⟨ ∘-minus-l f g (Ker.kernel (f - g)) ⟩≡
      (f - g) ∘ Ker.kernel (f - g)                        ≡⟨ Ker.equal (f - g) ⟩≡
      ∅.zero→ ∘ Ker.kernel (f - g)                        ≡⟨ ∅.zero-∘r _ ∙ 0m-unique ⟩≡
      0m                                                  ∎
    equ .universal {e' = e'} p = Ker.universal (f - g) {e' = e'} $
      (f - g) ∘ e'         ≡˘⟨ ∘-minus-l _ _ _ ⟩≡˘
      f ∘ e' - g ∘ e'      ≡⟨ ap (f ∘ e' -_) (sym p) ⟩≡
      f ∘ e' - f ∘ e'      ≡⟨ Hom.inverser ⟩≡
      0m                   ≡˘⟨ ∅.zero-∘r _ ∙ 0m-unique ⟩≡˘
      Zero.zero→ ∅ ∘ e'    ∎
    equ .factors = Ker.factors _
    equ .unique = Ker.unique (f - g)

By a standard characterisation of finite limits in terms of finite products and binary equalisers, the construction of “difference kernels” above implies that any pre-abelian category is finitely complete.

  finitely-complete : Finitely-complete C
  finitely-complete =
    with-equalisers C has-terminal has-prods λ f g →
      record { has-is-eq = difference-kernel }

Finite biproducts🔗

An interesting property of $\mathbf{Ab}\text{-enriched}$ categories is the coincidence of finite products and finite coproducts: not only is there a map² $a\bigsqcup b\to a\times b\text{,}$ defined from the universal properties, but it is also an isomorphism. This is, at least to the author, mildly unexpected, but it follows from the properties of zero morphisms.

More generally, suppose that $F:[n]\to \mathcal{A}$ is a finite family of objects in an $\mathbf{Ab}\text{-category.}$ If $F$ has both a coproduct $\coprod F$ and a product $\prod F$ in $\mathcal{A}\text{,}$ then we can define a map $\coprod F\to \prod F$ by giving a family of morphisms $F_i\to \prod F\text{,}$ which amounts to defining a family of morphisms $F_i\to F_j$³. Since $[n]$ is discrete, we can define this family to be $\mathrm{id}:F_i\to F_i$ when $i=j$ and $0:F_i\to F_j$ everywhere else!

What we actually prove in this module is a slight variation: we directly construct, given a product $\prod F\text{,}$ the structure of a coproduct on $\prod F$. Uniqueness of coproducts then implies that, if some other $\coprod F$ exists, then it must be isomorphic to $\coprod F\text{.}$

module _ (A : Ab-category C) {I : Nat} (F : Fin I → C .Precategory.Ob)
         (ip : Indexed-product C F) where
  private
    module A = Ab-category A
    module ip = Indexed-product ip
  open Cat.Abelian.NAry A

The first thing we’ll prove is a compatibility condition between tupling and sums: A sum of tuples is a tuple of sums. In the binary case, we’re showing that $(a,b)+(c,d)$ is $(a+c,b+d)\text{.}$

  tuple-sum : ∀ {j} {R} (f : Fin j → ∀ i → A.Hom R (F i))
        → ip.tuple (λ i → ∑ₕ j (λ j → f j i))
        ≡ ∑ₕ j λ j → ip.tuple (f j)
  tuple-sum {j} f = sym $ ip.unique _ λ i →
    ip.π i A.∘ ∑ₕ j (λ i → ip.tuple (f i))   ≡⟨ ∑-∘-left {j = j} _ ⟩≡
    ∑ₕ j (λ j → ip.π i A.∘ ip.tuple (f j))   ≡⟨ ∑-path {j} _ (λ j → ip.commute) ⟩≡
    ∑ₕ j (λ j → f j i)                       ∎

We then define our function ${\delta }_{i,j}:F_i\to F_j$ which is the identity on the diagonal.

  private
    δ' : (i j : Fin I) → Dec (i ≡ᵢ j) → A.Hom (F i) (F j)
    δ' i j (yes reflᵢ) = A.id
    δ' i j (no x) = A.0m

    δ : ∀ i j → A.Hom (F i) (F j)
    δ i j = δ' i j (i ≡ᵢ? j)

    δᵢⱼ : ∀ i j → ¬ i ≡ j → (d : Dec (i ≡ᵢ j)) → δ' i j d ≡ A.0m
    δᵢⱼ i j i≠j (yes i=j) = absurd (i≠j (Id≃path.to i=j))
    δᵢⱼ i j i≠j (no _)    = refl

We can now define a factoring of the identity on $\prod F$ through a — hypothetical — $\coprod F\text{.}$ A “splitting” map $\prod F\to \prod F\text{,}$ which works by summing (over $j\text{)}$ the tupling (over $i\text{)}$ of ${\delta }_{i,j}{\pi }_j\text{;}$ and since tupling commutes with sums, we conclude that this is the tupling over $i$ of a bunch of tuples, zero on every component except for the one corresponding to their index in the sum. In the binary case, we’re showing that

  split = ∑ₕ I λ j → ip.tuple λ i → δ j i A.∘ ip.π j

  private
    split-remark : A.id ≡ split
    split-remark = ip.unique ip.π (λ _ → A.idr _) ∙ sym (ip.unique _ πΣδπ) where
      sum-δ-π : ∀ i → ∑ {I} _ (λ j → δ j i A.∘ ip.π j) ≡ ip.π i
      sum-δ-π i = ∑-diagonal-lemma (Abelian→Group-on (A.Abelian-group-on-hom _ _)) {I} i _
        (A.eliml refl) λ j i≠j →
          ap₂ A._∘_ (δᵢⱼ j i (λ e → i≠j (sym e)) (j ≡ᵢ? i)) refl ∙ A.∘-zero-l

      πΣδπ : ∀ i → ip.π i A.∘ split ≡ ip.π i
      πΣδπ i =
        ip.π i A.∘ ∑ₕ I (λ i → ip.tuple λ j → δ i j A.∘ ip.π i) ≡⟨ ap (ip.π i A.∘_) (sym (tuple-sum {I} _)) ⟩≡
        ip.π i A.∘ ip.tuple (λ i → ∑ₕ I λ j → δ j i A.∘ ip.π j) ≡⟨ ip.commute ⟩≡
        ∑ₕ I (λ j → δ j i A.∘ ip.π j)                           ≡⟨ sum-δ-π i ⟩≡
        ip.π i                                                  ∎

We can now use this split morphism to construct the coproduct structure on $\prod F\text{.}$ First, the i-th coprojection ${\iota }_i:F_i\to \prod F$ is a tuple where all but the $i\text{-th}$ coordinate are $0\text{,}$ and $i$ is one. That is: it’s the tuple over $j$ of ${\delta }_{i,j}\text{!}$

  open Indexed-coproduct
  open is-indexed-coproduct
  coprod : Indexed-coproduct C F
  coprod .ΣF = ip.ΠF
  coprod .ι i = ip.tuple (δ i)

We now need to define the “match” function: Given a family $f:F_i\to Y\text{,}$ how do we extend this to a (unique) map $m_f$ satisfying $m_f{\iota }_j=f_j\text{?}$ Well, one potential approach is define $m_f$ to be some kind of sum — let’s say it’s a sum over $f_i^{\prime }\text{,}$ where $f_i^{\prime }$ is something we’ll define later. We can still calculate

so we have to choose $f_i^{\prime }$ such that $f_i^{\prime }$ is $f$ when $i=j\text{,}$ and $0$ otherwise, so only the $f$ term contributes to the above sum. And we know that, composed with ${\iota }_j\text{,}$ the $j\text{-th}$ projection is the identity function, and all others are $0$ — so if we define $f_i^{\prime }=f{\pi }_i\text{,}$ then we certainly have $({\sum }_i{f}_i^{\prime }){\iota }_j$ = $f\text{!}$

  coprod .has-is-ic = ico where
    m : ∀ {Y} → (∀ i → A.Hom (F i) Y) → A.Hom (ip .Indexed-product.ΠF) Y
    m f = ∑ₕ I λ j → f j A.∘ ip.π j

    ico : is-indexed-coproduct C F _
    ico .match f = m f
    ico .commute {i = i} {f = f} =
      m f A.∘ ip.tuple (δ i)                           ≡⟨ ∑-∘-right {I} _ ⟩≡
      ∑ₕ I (λ j → (f j A.∘ ip.π j) A.∘ ip.tuple (δ i)) ≡⟨ remark ⟩≡
      f i                                              ∎

      where
        remark = ∑-diagonal-lemma (Abelian→Group-on (A.Abelian-group-on-hom _ _)) {I} i
          (λ j → (f j A.∘ ip.π j) A.∘ ip.tuple (λ v → δ i v))
          (A.cancelr ip.commute)
          λ j i≠j → A.pullr (ip.commute ∙ δᵢⱼ i j i≠j (i ≡ᵢ? j))
                  ∙ A.∘-zero-r

And how do we show uniqueness? Using our remark about the split morphism defined above! It shows that any map $m^{\prime }:\prod F\to Y$ has to factor through something that looks a lot like our definition of $m_f$ above, and if it also satisfies $h{\iota }_j=f_j\text{,}$ then a bit of massaging shows it is exactly $m_f\text{.}$

    ico .unique {h = h} f prf =
      h                                                    ≡⟨ A.intror (sym split-remark) ⟩≡
      h A.∘ split                                          ≡⟨ ∑-∘-left {I} _ ⟩≡
      ∑ₕ I (λ i → h A.∘ ip.tuple (λ j → δ i j A.∘ ip.π i)) ≡⟨ ∑-path {I} _ (λ i → ap (h A.∘_) (sym (tuple∘ C F ip _))) ⟩≡
      ∑ₕ I (λ i → h A.∘ ip.tuple (λ j → δ i j) A.∘ ip.π i) ≡⟨ ∑-path {I} _ (λ i → A.pulll (prf i)) ⟩≡
      ∑ₕ I (λ i → f i A.∘ ip.π i)                          ≡⟨⟩
      m f                                                  ∎