open import Cat.Bi.Base
open import Cat.Prelude

module Cat.Bi.Diagram.Adjunction where

open _=>_

module _ {o ℓ ℓ'} (B : Prebicategory o ℓ ℓ') where
  private module B = Prebicategory B

Adjunctions in a bicategory🔗

Let $\mathbf{B}$ be a bicategory, $A,B:\mathbf{B}$ be objects, and $f:A\to B$ and $g:B\to A$ be 1-cells. Generalising the situation where $f$ and $g$ are functors, we say they are adjoints if there exist 2-cells $\eta :\mathrm{id}\to gf$ and $\epsilon :fg\to \mathrm{id}$ (the unit and counit respectively), satisfying the equations

and

called the triangle identities (because of their shape) or zigzag identities (because it sounds cool). Note that we have to insert appropriate associators and unitors in order to translate the diagrams above into equations that are well-typed in a (weak) bicategory.

  record _⊣_ {a b : B.Ob} (f : a B.↦ b) (g : b B.↦ a) : Type ℓ' where
    field
      η : B.id B.⇒ (g B.⊗ f)
      ε : (f B.⊗ g) B.⇒ B.id

      zig : B.Hom.id ≡ B.λ← f B.∘ (ε B.◀ f) B.∘ B.α← f g f B.∘ (f B.▶ η) B.∘ B.ρ→ f
      zag : B.Hom.id ≡ B.ρ← g B.∘ (g B.▶ ε) B.∘ B.α→ g f g B.∘ (η B.◀ g) B.∘ B.λ→ g

This means the triangle identities, rather than simply expressing a compatibility relation between $\eta$ and $\epsilon$ as is the case for adjoint functors, instead exhibit a complicated compatibility relation between $\eta \text{,}$ $\epsilon \text{,}$ and the structural isomorphisms (the unitors and associator) of the ambient bicategory.